什么是对象？在面向对象编程中，对象就是指由当作完整实体的操作和数据组成的变量。对象是基于特定模型的，在对象中客户使用对象的服务通过由一组方法或相关函数的接口访问对象的数据，然后客户端可以调用这些方法执行某中操作。ActiveX 组件是建立 Web 应用程序的关键，组件提供了在脚本中执行任务的对象。ActiveX 组件是一个文件，该文件包含执行某项或一组任务的代码，由于组件可以执行公用任务，这样程序员们就不必自己去创建执行这些任务的代码。可以利用组件作为脚本和基于 Web 应用程序的基本构造块。只要知道如何访问组件提供的对象，即使是位编写脚本的新手，也可以在不了解组件运作方式的情况下编写脚本。总之，组件使您不用学习编程就能够编写强大的脚本。组件是包含在动态链接库 .dll 或可执行文件 .exe 中的可执行代码。组件可以提供一个或多个对象以及对象的方法和属性。要使用组件提供的对象，请创建对象的实例并将这个新的实例分配变量名。使用 ASP 的 Server.CreateObject 方法可以创建对象的实例，使用脚本语言的变量分配指令可以为对象实例命名。如下例：
Set db=Server.CreateObject("ADODB.Connection")
这里的变量 db 就是 ASP 程序创建的访问数据库的对象实例。
Active Server Pages 提供了可在脚本中使用的内建对象。这些对象使用户更容易收集通过浏览器请求发送的信息、响应浏览器以及存储用户信息 , 从而使对象开发者摆脱了很多繁琐的工作。目前的 ASP 版本总共提供了六个内建对象，下面让我们将通过实例分别来进行学习。
4.1 ASP内建对象Request
可以使用 Request 对象访问任何基于 HTTP 请求传递的所有信息，包括从 HTML 表格用 POST 方法或 GET 方法传递的参数、cookie 和用户认证。Request 对象使您能够访问客户端发送给服务器的二进制数据。
Request 的语法 :
Request[. 集合 | 属性 | 方法 ]( 变量 )
在这里将挑选一些常用的对象语法进行分析
1、Form
Form 集合通过使用 POST 方法的表格检索邮送到 HTTP 请求正文中的表格元素的值。
语法
Request.Form(element)[(index)|.Count]
参数
element 指定集合要检索的表格元素的名称。
index 可选参数，使用该参数可以访问某参数中多个值中的一个。它可以是 1 到 Request.Form(parameter).Count 之间的任意整数。
Count 集合中元素的个数
Form 集合按请求正文中参数的名称来索引。Request.Form(element) 的值是请求正文中所有 element 值的数组。通过调用 Request.Form(element).Count 来确定参数中值的个数。如果参数未关联多个值，则计数为 1。如果找不到参数，计数为 0。要引用有多个值的表格元素中的单个值，必须指定 index 值。index 参数可以是从 1 到 Request.Form(element).Count 中的任意数字。如果引用多个表格参数中的一个，而未指定 index 值，返回的数据将是以逗号分隔的字符串。
可以使用重述符来显示表格请求中的所有数据值。
对于 hobby 参数，您可以使用下面的脚本检索这些值。
<html>
<head><title></title>
</head>
<body>
<p> 请填写你的爱好 </p>
<form method="POST" action="form.asp">
<p><input type="text" name="hobby" size="20"><br>
<input type="checkbox" name="hobby" value=" 足球 "> 足球
<input type="checkbox" name="hobby" value=" 乒乓球 "> 乒乓球 </p> <p>
<input type="submit" value=" 发送 " name="B1">
<input type="reset" value=" 重填 " name="B2"></p>
</form>
<% For Each i In Request.Form("hobby") Response.Write i & "<BR>" Next
%>
</body>
</html>
将以上代码剪贴到记事簿中（注意将“<”后面的空格去掉），保存为 form.asp 文件并运行，request 对象可以根据你在 form 中填入或选择元素内容的不同将元素逐个显示出来。
当然使用 For...Next 循环也可以生成同样的输出，如下所示 :
<%
For i = 1 To Request.Form("hobby").Count
Response.Write Request.Form("hobby")(i) & "<BR>"Next
%>
2、QueryString
QueryString 集合检索 HTTP 查询字符串中变量的值 ,HTTP 查询字符串由问号 (?) 后的值指定。如：
<A HREF= "example.asp?string=this is a sample">string sample</A>
生成值为 "this is a sample" 的变量名字符串。通过发送表格或由用户在其浏览器的地址框中键入查询也可以生成查询字符串。
语法
Request.QueryString(variable)[(index)|.Count]
QueryString 集合可以让您以名称检索 QUERY_STRING 变量。Request.QueryString( 参数 ) 的值是出现在 QUERY_STRING 中所有参数的值的数组。通过调用Request.QueryString(parameter).Count 可以确定参数有多少个值。
我们也可以使用 QueryString 来达到与前一个范例相同的功能。只需要将 request.form 部分替换如下：
<%
For Each i In Request.querystring("hobby")
Response.Write i & "<BR>"
Next
%>
3、Cookies
什么是 Cookie?Cookie 其实是一个标签，当你访问一个需要唯一标识你的站址的 WEB 站点时，它会在你的硬盘上留下一个标记，下一次你访问同一个站点时，站点的页面会查找这个标记。每个 WEB 站点都有自己的标记，标记的内容可以随时读取，但只能由该站点的页面完成。每个站点的 Cookie 与其他所有站点的 Cookie 存在同一文件夹中的不同文件内（你可以在 Windows 的目录下的 Cookie 文件夹中找到它们）。一个 Cookie 就是一个唯一标识客户的标记，Cookie 可以包含在一个对话期或几个对话期之间某个 WEB 站点的所有页面共享的信息，使用 Cookie 还可以在页面之间交换信息。Request 提供的 Cookies 集合允许用户检索在 HTTP 请求中发送的 cookie 的值。这项功能经常被使用在要求认证客户密码以及电子公告板、WEB 聊天室等 ASP 程序中。
语法
Request.Cookies(cookie)[(key)|.attribute]
参数
cookie 指定要检索其值的 cookie。
key 可选参数，用于从 cookie 字典中检索子关键字的值。
attribe 指定 cookie 自身的有关信息。如：HasKeys 只读，指定 cookie 是否包含关键字。
可以通过包含一个 key 值来访问 cookie 字典的子关键字。如果访问 cookie 字典时未指定 key，则所有关键字都会作为单个查询字符串返回。例如，如果 MyCookie 有两个关键字 , First 和 Second，而在调用 Request.Cookies 时并未指定其中任何一个关键字，那么将返回下列字符串。
First=firstkeyvalue&Second=secondkeyvalue
如果客户端浏览器发送了两个同名的 cookie，那么 Request.Cookie 将返回其中路径结构较深的一个。例如，如果有两个同名的的 cookie，但其中一个的路径属性为 /www/ 而另一个为 /www/home/，客户端浏览器同时将两个 cookie 都发送到 /www/home/ 目录中，那么 Request.Cookie 将只返回第二个 cookie。
要确定某个 cookie 是不是 cookie 字典（cookie 有否有关键字），可使用下列脚本。
<%= Request.Cookies("myCookie").HasKeys %>
如果 myCookie 是一个 cookie 字典，则前面的赋值为 TRUE。否则，为 FALSE。下面我们来看看一个 cookie 的应用实例：
<%
nickname=request.form("nick")response.cookies("nick")=nickname
' 用 response 对象将用户名写入 Cookie 之中
response.write " 欢迎 "&request.cookies("nick")&" 光临小站！"
%>
<html><head><meta http-equiv="Content-Type" content="text/html; charset=gb2312">
<title>cookie</title>
<meta name="GENERATOR" content="Microsoft FrontPage 3.0"></head>
<body>
<form method="POST" action="cookie.asp">
<p><input type="text" name="nick" size="20">
<input type="submit" value=" 发送 " name="B1"><input type="reset" value=" 重填 " name="B2"></p></form>
</body></html>
这其实是一个在基于 WEB 的 BBS 或 CHAT 的 ASP 程序中常用的手法，它将用户在起始页面上填入的姓名保存在 cookie 中，这样后面的程序就可以很容易地调用该用户的 nick 了。
4、ServerVariables
大家都知道在浏览器中浏览网页的时候使用的传输协议是 HTTP，在 HTTP 的标题文件中会记录一些客户端的信息，如 : 客户的 IP 地址等等，有时服务器端需要根据不同的客户端信息做出不同的反映，这时候就需要用 ServerVariables 集合获取所需信息。
语法
Request.ServerVariables ( 服务器环境变量 )
由于服务器环境变量较多，仅将一些常用的变量在下表中列出 :
ALL_HTTP
客户端发送的所有 HTTP 标题文件。
CONTENT_LENGTH
客户端发出内容的长度。
CONTENT_TYPE
内容的数据类型。如：“text/html”。同附加信息 的查询一起使用，如 HTTP 查询 GET、POST 和 PUT。
LOCAL_ADDR
返回接受请求的服务器地址。如果在绑定多 个 IP 地址的多宿主机器上查找请求所使用的地址 时，这条变量非常重要。
LOGON_USER
用户登录 Windows NT 的帐号。
QUERY_STRING
查询 HTTP 请求中问号（?）后的信息。
REMOTE_ADDR
发出请求的远程主机 (client) 的 IP 地址。
REMOTE_HOST
发出请求的主机 (client) 名称。如果服务器无此 信息，它将设置为空的 MOTE_ADDR 变量。
REQUEST_METHOD
该方法用于提出请求。相当于用于 HTTP 的 GET、HEAD、POST等 等。
SERVER_NAME
出现在自引用 URL 中的服务器主机名、DNS 化名 或 IP 地址。
SERVER_PORT
发送请求的端口号。
我们可以使用以下脚本打印出所有的服务器环境变量。
<TABLE>
<TR><TD><B>Server Variable</B></TD><TD><B>Value</B></TD></TR><% For Each name In Request.ServerVariables %>
<TR><TD> <%= name %> </TD><TD> <%= Request.ServerVariables(name) %> </TD></TR></TABLE>
<% Next %>
本节我们详细学习了 ASP 内建对象中的 request 对象，这也是 ASP 程序中使用最频繁的对象，希望大家多多实践。
4.2 ASP内建对象Response
在上一节中作者给大家详细介绍了 ASP 内建对象之一 Request 的使用方法，相信各位读者通过一系列的实践已经能够熟练掌握，本节将继续给大家介绍 ASP 的另一个内建对象 Response。
4.2.1 属性
1、Buffer
Buffer 属性指示是否缓冲页输出。当缓冲页输出时，只有当前页的所有服务器脚本处理完毕或者调用了 Flush 或 End 方法后，服务器才将响应发送给客户端浏览器，服务器将输出发送给客户端浏览器后就不能再设置 Buffer 属性。因此应该在 .asp 文件的第一行调用 Response.Buffer。
2、Charset
Charset 属性将字符集名称附加到 Response 对象中 content-type 标题的后面。对于不包含 Response.Charset 属性的 ASP 页，content-type 标题将为 :content-type:text/html。
我们可以在 .asp 文件中指定 content-type 标题，如 :
<% Response.Charset="gb2312") %>
将产生以下结果 :
content-type:text/html; charset=gb2312
注意，无论字符串表示的字符集是否有效，该功能都会将其插入 content-type 标题中。且如果某个页包含多个含有 Response.Charset 的标记，则每个 Response.Charset 都将替代前一个 CharsetName。这样，字符集将被设置为该页中 Response.Charset 的最后一个实例所指定值。
3、ContentType
ContentType 属性指定服务器响应的 HTTP 内容类型。如果未指定 ContentType，默认为 text/HTML。
4、Expires
Expires 属性指定了在浏览器上缓冲存储的页距过期还有多少时间。如果用户在某个页过期之前又回到此页，就会显示缓冲区中的页面。如果设置 response.expires=0，则可使缓存的页面立即过期。这是一个较实用的属性，当客户通过 ASP 的登陆页面进入 WEB 站点后，应该利用该属性使登陆页面立即过期，以确保安全。
5、ExpiresAbsolute
与 Expires 属性不同 ExpiresAbsolute 属性指定缓存于浏览器中的页面的确切到期日期和时间。在未到期之前，若用户返回到该页，该缓存中的页面就显示。如果未指定时间，该主页在当天午夜到期。如果未指定日期，则该主页在脚本运行当天的指定时间到期。如下示例指定页面在 1998 年 12 月 10 日上午 9:00 分 30 秒到期。
<% Response.ExpiresAbsolute=#Dec 12,1998 9:00:30# %>
4.2.2 方法
1、Clear
可以用 Clear 方法清除缓冲区中的所有 HTML 输出。但 Clear 方法只清除响应正文而不清除响应标题。可以用该方法处理错误情况。但是如果没有将 Response.Buffer 设置为 TRUE，则该方法将导致运行时错误。
2、End
End 方法使 Web 服务器停止处理脚本并返回当前结果。文件中剩余的内容将不被处理。如果 Response.Buffer 已设置为 TRUE，则调用 Response.End 将缓冲输出。
3、Flush
Flush 方法立即发送缓冲区中的输出。如果没有将 Response.Buffer 设置为 TRUE，则该方法将导致运行时错误。
4、Redirect
Redirect 方法使浏览器立即重定向到程序指定的 URL。这也是一个我们经常用到方法，这样程序员就可以根据客户的不同响应，为不同的客户指定不同的页面或根据不同的情况指定不同的页面。一旦使用了 Redirect 方法任何在页中显式设置的响应正文内容都将被忽略。然而，此方法不向客户端发送该页设置的其他 HTTP 标题，将产生一个将重定向 URL 作为链接包含的自动响应正文。Redirect 方法发送下列显式标题，其中 URL 是传递给该方法的值。如:
<% Response.redirect("www.chinabyte.com") %>
5、Write
Write 方法是我们平时最常用的方法之一，它是将指定的字符串写到当前的 HTTP 输出。
4.2.3 集合
Response 对象只有一个集合 --Cookie
Cookies 集合设置 cookie 的值。若指定的 cookie 不存在，则创建它。若存在，则设置新的值并且将旧值删去。
语法
Response.Cookies(cookie)[(key)|.attribute]=value
这里的 cookie 是指定 cookie 的名称。而如果指定了 key，则该 cookie 就是一个字典。attribute 指定 cookie 自身的有关信息。attribute 参数可以是下列之一 :
Domain 若被指定，则 cookie 将被发送到对该域的请求中去。
Expires 指定 cookie 的过期日期。为了在会话结束后将 cookie 存储在客户端磁盘上，必须设置该日期。若此项属性的设置未超过当前日期，则在任务结束后 cookie 将到期。
HasKeys 指定 cookie 是否包含关键字。
Path 若被指定，则 cookie 将只发送到对该路径的请求中。如果未设置该属性，则使用应用程序的路径。
至此，我们已经学习的 Response 对象的所有属性、方法和集合的理论知识，下面给大家演示一段简单的程序，通过实践让大家加深理解。
<%
Dim user
Dim flag
Dim pwd
Dim say
Response.buffer=true ' 开启缓冲页面功能
Response.ContentType="text/HTML"
Response.Charset="gb2312"
user=Request.Form("username")
pwd=Request.Form("password")
say=Request.QueryString("say")
%>
<form method="POST" action="asp7.asp">
<p> 用户名 :<input type="text" name="username" size="12"><br>
口 令 :<input type="password" name="password" size="12"><br>
<input type="submit" value=" 提交 " name="B1"><input type="reset" value=" 取消 " name="B2"></p></form>
<%
If say=1 then
Response.Write " 欢迎光临 !"
End If
If say > 1 then
Response.Write " 欢迎再次光临!"
End If
If user="Adm" and pwd="shusheng" Then
Response.Expires=1 ' 设置该页面在浏览器的缓冲中存储 1 分钟后过期。
flag=1
ElseIf user="guest" and pwd="guest" Then
Response.Expires=0 ' 使缓存的页面立即过期。
Response.Clear ' 清空存储在缓存中的页面
flag=2
ElseIf user="vip" and pwd="vip" Then
Response.Write " 欢迎 VIP 光临"
flag=3
Else
flag=0
Response.End ' 立即停止脚本处理，并将缓存中的页面输出
End If
Response.write "<p><a href='asp7b.asp?flag="&flag&"'> 动态网站设计实践练习 </a></p>"
%>
<p> 动态网站设计练习 </p>
再将以下程序保存为 asp7b.asp。
<%
Dim saysay=Request.QueryString("flag")
Select case say
case "1"
Response.Redirect "asp7.asp?say=1"
case "2"
Response.Redirect "asp7.asp?say=2"
case "3"
Response.Redirect "asp7.asp?say=3"
case "0"
Response.Redirect "asp7.asp?say=0"
End Select
%>
将这两个程序放在有执行权限的 WEB 虚拟目录下，并以 http 方式访问 asp7.asp。在这两个程序中我们充分运用了至今为止所学过的两个 ASP 内建对象 :Request 和 Response。当你第一次访问 asp7.asp 文件时，页面上出现一个 Form 并提示输入用户名和口令。
因为我们设置了页面缓存，当使用 guest 登陆时，判断程序自动清空其之前所有存储在缓存中的页面，而仅将其后脚本程序执行的结果显示出来。
4.3 ASP内建对象Application 和 Session
在上一节给大家详细介绍了 ASP 内建对象 Response 的使用方法，在这一节中继续给大家介绍另两个非常实用且重要的 ASP 的内建对象 Application 和 Session。
在 ASP 的内建对象中除了用于发送、接收和处理数据的对象外，还有一些非常实用的代表 Active Server 应用程序和单个用户信息的对象。
4.3.1 Application
让我们先来看看 Application 对象。在同一虚拟目录及其子目录下的所有 .asp 文件构成了 ASP 应用程序。我们非但可以使用 Application 对象，在给定的应用程序的所有用户之间共享信息，并在服务器运行期间持久的保存数据。而且，Application 对象还有控制访问应用层数据的方法和可用于在应用程序启动和停止时触发过程的事件。
下面就让我们一起来学习 Application 对象。
4.3.1.1 属性
虽然 Application 对象没有内置的属性，但我们可以使用以下句法设置用户定义的属性也可称为集合。
Application(" 属性 / 集合名称 ")= 值
我们可以使用如下脚本声明并建立 Application 对象的属性。
<%
Application("MyVar") = "Hello"
Set Application("MyObj") = Server.CreateObject("MyComponent")
%>
一旦我们分配了 Application 对象的属性，它就会持久地存在，直到关闭 WEB 服务器服务使得 Application 停止。由于存储在 Application 对象中的数值可以被应用程序的所有用户读取，所以 Application 对象的属性特别适合在应用程序的用户之间传递信息。
4.3.1.2 方法
Application 对象有两个方法，它们都是用于处理多个用户对存储在 Application 中的数据进行写入的问题
1、Lock 方法禁止其他客户修改 Application 对象的属性。
Lock 方法阻止其他客户修改存储在 Application 对象中的变量，以确保在同一时刻仅有一个客户可修改和存取 Application 变量。如果用户没有明确调用 Unlock 方法，则服务器将在 .asp 文件结束或超时后即解除对 Application 对象的锁定。
让我们来看看下面这段用 Application 来记录页面访问次数的程序 :
<%
Dim NumVisitsNumVisits=0
Application.LockApplication("NumVisits") = Application("NumVisits") + 1
Application.Unlock
%>
欢迎光临本网页，你是本页的第 <%= Application("NumVisits") %> 位访客 !
将以上脚本保存在你的 .asp 文件中，就轻而易举地给你的页面添加了一个计数器。
2、和 Lock 方法相反，Unlock 方法允许其他客户修改 Application 对象的属性。
在上面的例子中，上述例子中，Unlock 方法解除对象的锁定，使得下一个客户端能够增加 NumVisits 的值。
4.3.1.3 事件
1、Application_OnStart
Application_OnStart 事件在首次创建新的会话 ( 即 Session_OnStart 事件 ) 之前发生。当 WEB 服务器启动并允许对应用程序所包含的文件进行请求时就触发 Application_OnStart 事件。Application_OnStart 事件的处理过程必须写在 Global.asa 文件之中。
Application_OnStart 事件的语法如下 :
<SCRIPT LANGUAGE=ScriptLanguage RUNAT=Server>
Sub Application_OnStart. . .
End Sub
</SCRIPT>
2、Application_OnEnd
Application_OnEnd 事件在应用程序退出时于 Session_OnEnd 事件之后发生，Application_OnEnd 事件的处理过程也必须写在 Global.asa 文件之中。
下面让我们来看看在使用 Application 对象时必须注意的一些事项。
不能在 Application 对象中存储 ASP 内建对象。例如，下面的每一行都返回一个错误。
<%
Set Application("var1")=Session
Set Application("var2")=Request
Set Application("var3")=Response
Set Application("var4")=Server
Set Application("var5")=Application
Set Application("var6")=ObjectContext
%>
若您将一个数组存储在 Application 对象中，请不要直接更改存储在数组中的元素。例如，下列的脚本无法运行。
<% Application("StoredArray")(3) = "new value" %>
这是因为 Application 对象是作为集合被实现的。数组元素 StoredArray(3) 未获得新的赋值。而此值将包含在 Application 对象集合中，并将覆盖此位置以前存储的任何信息。建议您在将数组存储在 Application 对象中时，在检索或改变数组中的对象前获取数组的一个副本。在对数组操作时，您应再将数组全部存储在 Application 对象中，这样您所做的任何改动将被存储下来。下列的脚本对此进行演示。
<%
dim MyArray()
Redim MyArray(5)
MyArray(0)="hello"
MyArray(1)="some other string"
Application.Lock
Application("StoredArray")=MyArray
Application.Unlock
Response.Redirect "asp8b.asp"
%>
<%
LocalArray=Application("StoredArray")
LocalArray(1)=" there"
Response.Write LocalArray(0)&LocalArray(1)
Application.Lock
Application("StoredArray")=LocalArray
Application.Unlock
%>
4.3.2 Session
与 Application 对象具有相近作用的另一个非常实用的 ASP 内建对象就是 Session。我们可以使用 Session 对象存储特定的用户会话所需的信息。当用户在应用程序的页之间跳转时，存储在 Session 对象中的变量不会清除，而用户在应用程序中访问页面时，这些变量始终存在。当用户请求来自应用程序的 Web 页时，如果该用户还没有会话，则 Web 服务器将自动创建一个 Session 对象。当会话过期或被放弃后，服务器将终止该会话。
通过向客户程序发送唯一的 Cookie 可以管理服务器上的 Session 对象。当用户第一次请求 ASP 应用程序中的某个页面时，ASP 要检查 HTTP 头信息，查看是否有在报文中有名为 ASPSESSIONID 的 Cookie 发送过来，如果有，则服务器会启动新的会话，并为该会话生成一个全局唯一的值，在把这个值作为新 ASPSESSIONID Cookie 的值发送给客户端，正是使用这种 Cookie，可以访问存储在服务器上的属于客户程序的信息。Session 对象最常见的作用就是存储用户的首选项。例如，如果用户指明不喜欢查看图形，就可以将该信息存储在 Session 对象中。另外其还经常被用在鉴别客户身份的程序中。要注意的是，会话状态仅在支持 cookie 的浏览器中保留，如果客户关闭了 Cookie 选项，Session 也就不能发挥作用了。
4.3.2.1 属性
1、SessionID
SessionID 属性返回用户的会话标识。在创建会话时，服务器会为每一个会话生成一个单独的标识。会话标识以长整形数据类型返回。在很多情况下 SessionID 可以用于 WEB 页面注册统计。
2、TimeOut
Timeout 属性以分钟为单位为该应用程序的 Session 对象指定超时时限。如果用户在该超时时限之内不刷新或请求网页，则该会话将终止。
4.3.2.2 方法
Session 对象仅有一个方法，就是 Abandon，Abandon 方法删除所有存储在 Session 对象中的对象并释放这些对象的源。如果您未明确地调用 Abandon 方法，一旦会话超时，服务器将删除这些对象。当服务器处理完当前页时，下面示例将释放会话状态。
<% Session.Abandon %>
4.3.2.3 事件
Session 对象有两个事件可用于在 Session 对象启动和释放是运行过程。
1、Session_OnStart 事件在服务器创建新会话时发生。服务器在执行请求的页之前先处理该脚本。Session_OnStart 事件是设置会话期变量的最佳时机，因为在访问任何页之前都会先设置它们。
尽管在 Session_OnStart 事件包含 Redirect 或 End 方法调用的情况下 Session 对象仍会保持，然而服务器将停止处理 Global.asa 文件并触发 Session_OnStart 事件的文件中的脚本。
为了确保用户在打开某个特定的 Web 页时始终启动一个会话，就可以在 Session_OnStart 事件中调用 Redirect 方法。当用户进入应用程序时，服务器将为用户创建一个会话并处理 Session_OnStart 事件脚本。您可以将脚本包含在该事件中以便检查用户打开的页是不是启动页，如果不是，就指示用户调用 Response.Redirect 方法启动网页。程序如下 :
<SCRIPT RUNAT=Server Language=VBScript>
Sub Session_OnStart
startPage = "/MyApp/StartHere.asp"
currentPage = Request.ServerVariables("SCRIPT_NAME")
if strcomp(currentPage,startPage,1) then
Response.Redirect(startPage)
end if
End Sub
</SCRIPT>
上述程序只能在支持 cookie 的浏览器中运行。因为不支持 cookie 的浏览器不能返回 SessionID cookie，所以，每当用户请求 Web 页时，服务器都会创建一个新会话。这样，对于每个请求服务器都将处理 Session_OnStart 脚本并将用户重定向到启动页中。
2、Session_OnEnd 事件在会话被放弃或超时发生。
关于使用 Session 对象需要注意的事项 Application 对象相近，请参照前文。
会话可以通过以下三种方式启动 :
1、一个新用户请求访问一个 URL，该 URL 标识了某个应用程序中的 .asp 文件，并且该应用程序的 Global.asa 文件包含 Session_OnStart 过程。
2、用户在 Session 对象中存储了一个值。
3、用户请求了一个应用程序的 .asp 文件，并且该应用程序的Global.asa 文件使用 <OBJECT> 标签创建带有会话作用域的对象的实例。
如果用户在指定时间内没有请求或刷新应用程序中的任何页，会话将自动结束。这段时间的默认值是 20 分钟。可以通过在 Internet 服务管理器中设置“应用程序选项”属性页中的“会话超时”属性改变应用程序的默认超时限制设置。应依据您的 Web 应用程序的要求和服务器的内存空间来设置此值。例如，如果您希望浏览您的 Web 应用程序的用户在每一页仅停留几分钟，就应该缩短会话的默认超时值。过长的会话超时值将导致打开的会话过多而耗尽您的服务器的内存资源。对于一个特定的会话，如果您想设置一个小于默认超时值的超时值，可以设置 Session 对象的 Timeout 属性。例如，下面这段脚本将超时值设置为 5 分钟。
<% Session.Timeout = 5 %>
当然你也可以设置一个大于默认设置的超时值，Session.Timeout 属性决定超时值。你还可以通过 Session 对象的 Abandon 方法显式结束一个会话。例如，在表格中提供一个“退出”按钮，将按钮的 ACTION 参数设置为包含下列命令的 .asp 文件的 URL。
<% Session.Abandon %>
在本节我们学习了两个在 WEB 页面特别是基于 WEB 的 BBS 或 Chat 上经常使用 ASP 内建对象，由于这两个对象在实际运用中很实用，因此在下一节中将运用至此我们所学过的 4 个 ASP 内建对象，给大家演示一个完整的 ASP 应用程序，相信通过这个练习，能大大加深你对 ASP 应用程序的理解和掌握。
4.4 Global.asa文件的使用及Chat程序
在上一节中给大家详细介绍了两个非常实用的 ASP 内建对象 Application 和 Session 的使用方法。由于这两者的 OnStart、OnEnd 事件的脚本都必须在 Global.asa 文件中声明 , 因此，本节将给大家详细介绍 Global.asa 文件的使用方法。为使大家熟练掌握至今所学过的知识，本篇还将举出一个 ASP 的 Chat 程序，供各位参考。
下面向大家介绍 Global.asa 文件的使用方法。
什么是 Global.asa 文件？它其实是一个可选文件，程序编写者可以在该文件中指定事件脚本，并声明具有会话和应用程序作用域的对象。该文件的内容不是用来给用户显示的，而是用来存储事件信息和由应用程序全局使用的对象。该文件的名称必须是 Global.asa 且必须存放在应用程序的根目录中。每个应用程序只能有一个 Global.asa 文件。
在 Global.asa 文件中，如果包含的脚本没有用 <SCRIPT> 标记封装，或定义的对象没有会话或应用程序作用域，则服务器将返回错误。我们可以用任何支持脚本的语言编写 Global.asa 文件中包含的脚本。如果多个事件使用同一种脚本语言，就可以将它们组织在一组 <SCRIPT> 标记中。
在 Global.asa 文件中声明的过程只能从一个或多个与 Application_OnStart、Application_OnEnd、Session_OnStart 和 Session_OnEnd 事件相关的脚本中调用。在基于 ASP 的应用程序的 ASP 页中，它们是不可用的。如果要在应用程序之间共享过程，可在单独的文件中声明这些过程，然后使用服务器端包容 (SSI) 语句将该文件包含在调用该过程的 ASP 程序中。通常，包含文件的扩展名应为 .inc。
下面是一个很标准的 Global.asa 文件 :
<SCRIPT LANGUAGE="VBScript" RUNAT="Server">
'Session_OnStart 当客户首次运行 ASP 应用程序中的任何一个页面时运行
'Session_OnEnd 当一个客户的会话超时或退出应用程序时运行
'Application_OnStart 当任何客户首次访问该应用程序的首页时运行
'Application_OnEnd 当该站点的 WEB 服务器关闭时运行
</SCRIPT>
<SCRIPT LANGUAGE="VBScript" RUNAT="Server">
Sub Application_OnStart
VisitorCountFilename = Server.MapPath ("/ex2") + "\VisitCount.txt"
Set FileObject = Server.CreateObject("Scripting.FileSystemObject")
Set Out= FileObject.OpenTextFile (VisitorCountFilename, 1, FALSE, FALSE)
Application("visitors") = Out.ReadLine
Application("VisitorCountFilename") = VisitorCountFilename
End Sub
'=========================================================
SUB Application_OnEnd
Set FileOutObject = Server.CreateObject("Scripting.FileSystemObject")
Set Out= FileOutObject.CreateTextFile (Application("VisitorCountFilename"), TRUE,FALSE)
Out.WriteLine(application("visitors"))
End Sub
'=========================================================Sub Session_OnStart
Session.Timeout = 5
Application("visitors") = Application("visitors") + 1
Session("ID")=Session.SessionID
End Sub
</SCRIPT>
在这个 Global.asa 程序中，涉及到了 ASP 的 File Access 组件，它可以提供用于访问文件系统的方法、属性和集合。这将在以后 ASP 的组件中进行展开讨论。在这里，它起到了在服务器上创建新文件并对文件进行写操作的作用。这其实是一个 ASP 页面访问记数器应用程序的 Global 文件，首先当客户首次访问该应用程序的首页时 , 过程 Application_OnStart 定义了在服务器上指定的虚拟目录下新建一个 VisitCount.txt 的文本文件，并将文件的路径和内容保存在应用程序级的变量中。而当任何一个客户访问 ASP 应用程序中的任何一个页面时，过程 Session_OnStart 定义将应用程序级的变量 visitors 的值自动加一。这样，每当有客户访问页面时，变量 visitors 都将自动加一，以起到统计点击率的作用。由于变量 visitors 的值是存储在系统内存之中，所以如果服务器关闭或重新启动，存储在变量中的数据将自动丢失，所以通过定义过程 Application_OnEnd，在服务器关闭或重启之前将数据写入事先建立的文本文件之中，这样就能确保当服务器再次启动时，Application_OnStart 过程可以从 VisitCount.txt 文件中读取以前的统计数。
经过这段时间的学习，相信大家已经能够比较熟练的运用我们所学过的这些 ASP 内建对象来编写一些较简单的 ASP 应用程序，下面就举一个非常简单的 ASP WEB 聊天室程序:
<%@ Language=VBScript %>
<%
Response.Buffer=true ' 设置输出缓存，用于显示不同页面。
On error resume next ' 忽略程序出错部分
If Request.ServerVariables("Request_Method")="GET" then
%>
<form method="POST" action="chat.asp"><p>
<input type="text" name="nick" size="20" value="nick" style="background-color: rgb(192,192,192)"><br>
<input type="submit" value=" 进入聊天室 " name="B1" style="color: rgb(255,255,0); font-size: 9pt; background-color: rgb(0,128,128)">
<p><input type="hidden" name="log" size="20" value="1"><br></p>
</form>
<%
Response.End ' 结束程序的处理
Else
Response.clear ' 清空缓存中的内容
dim talk
If Request.Form("nick")<>"" then
' 判断客户是是否在聊天界面中
Session("nick")=Request.Form("nick")
End If
客户聊天界面
%>
<form method="POST" action="chat.asp" name=form1> <p><%=Session("nick")%> 说话：<input type="text" name="talk" size="50"><br>
<input type="submit" value=" 提交 " name="B1">
<input type="reset" value=" 取消 " name="B2"></p>
</form>
<A HREF="/asptest/shusheng/chat.asp"> 离开 </a><br><br>
<%
If Request.Form("log")<>1 then
If trim(Request.Form("talk"))="" then
talk=Session("nick")&" 沉默是金。"
Else
talk=trim(Request.Form("talk"))
' 去掉字符后的空格
End If
Application.lock
Application("show")="<table border='0' cellpadding='0' cellspacing='0' width='85%' ><tr><td width='100%' bgcolor='#C0C0C0'></td></tr><tr><td width='100%'><font color='#0000FF'> 来自 "&Request.ServerVariables("remote_addr")&" 的 "&Session("nick")&time&" 说：</font>"&talk&"</td></tr><tr><td width='100%' bgcolor='#C0C0C0'></td></tr><br>"&Application("show")
Application.UnLock
Response.Write Application("show")
End If
End If
%>
下面我们来对这个聊天室程序进行逐步的分析。
首先，由于聊天室的所有客户都要能够共享信息，所以不可避免的要用到具有应用程序级变量的对象 Application，这是建立 Chat 程序的关键所在，所有的谈话数据都存放在一个应用程序级变量中，以便让所有的客户读取。我们可以用所学过的
<% Application("show")=talk&Application("show") %>
接下来要考虑的是当不同的客户同时向 Chat 应用程序进行操作的时候如何处理。这个问题其实与在数据库中的两个用户同时写入同一个记录一样，如果两个用户同时对同一个应用程序级变量进行写操作，则一个用户所作的修改会被另一个用户的操作所覆盖，所以，如果对 Application 对象数据的并发访问不采取一定措施，则会导致当两个用户试图同时对 Asp 聊天室应用程序提交时，一个用户的提交内容会被另一个用户的提交内容所覆盖，在被参加到会话中的任何人看到之前就消失了。为了避免这类问题的出现，我们需要使用 Application 对象的 Lock 属性来约束只允许当前的用户编辑或增加 Application 对象的属性，这样当用户开始修改应用程序级变量开始，到 Application 对象被显式地 Unlocked 为止，Application 对象的属性只能被该用户编辑，如果此时有其他用户请求编辑 Application 对象，则这些用户要排队等待，知道应用程序被 Unlock 为止。如下所示 :
Application.lock
Application("show")=talk&Application("show")
Application.UnLock
现在整个程序的核心部分你已经了解了，下面考虑如何保存客户信息，这里我们要用到一个会话级变量，即将客户的 nick 保存在 Session 中。如:
Session("nick")=Request.Form("nick")
最后，我们要考虑的是如何仅在一个 .asp 文件中处理各种事件 , 如 : 客户登陆界面、客户聊天界面。由于客户第一次请求 .asp 文件时，采用的是简单的 HTTP GET 方式，但是当客户向页面上的表单字段中增加的数据并向自身提交表单后，.asp 文件会再次被请求，不过这次数据是经过 HTTP POST 方式进行传递的。文件被请求的方式可以用两种方法来确定。一是测试 Request.Form 集合是否包含成员，若没有，则表明没有发送给表单处理的数据。二是使用 Request.ServerVariables("Request_Method") 变量。如果表单是通过 HTTP GET 方式被请求的，则这个变量会返回“GET”，如果表单被提交处理则返回“POST”。由于后一种方法对于确定文件的请求方式更直接，所以我们使用如下代码进行判断 :
if Request.ServerVariables("Request_Method")="GET" then
由于我们设置了 ASP 缓存，所以当程序判断页面请求方式为 GET 时，程序运行 Response.End，来结束后面的所有操作，否则则运行 Response.clear, 清空缓存中已有的内容，并继续程序的运行。这样我们就得以用同一个 .asp 文件根据不同情况给客户显示不同的界面。
4.5 ASP内建对象Server
Server 对象提供对服务器上的方法和属性的访问 , 其中大多数方法和属性是作为实用程序的功能服务的。有了 Server 对象，你就可以在服务器上启动 ActiveX 对象例程，并使用 Active Server 服务提供象 HTML 和 URL 编码这样的函数。
4.5.1 语法
Server.property|method
4.5.2 属性
ScriptTimeout 超时值，在脚本运行超过这一时间之后即作超时处理。如下代码指定服务器处理脚本在 100 秒后超时。
<% Server.ScriptTimeout=100 %>
这里需要注意的是，通过使用元数据库中的 AspScriptTimeout 属性可以为 Web 服务或 Web 服务器设置缺省的 ScriptTimeout 值。ScriptTimeout 属性不能设置为小于在原数据库中指定的值。例如，如果 NumSeconds 设置为 60，而元数据库设置包含了默认值 90 秒，则脚本在 90 秒后超时。
4.5.3 方法
1、HTMLEncode 方法
HTMLEncode 方法允许你对特定的字符串进行 HTML 编码，虽然 HTML 可以显示大部分你写入 ASP 文件中的文本，但是当你需要实际包含 HTML 标记中所使用的字符，就会遇到问题。这是因为，当浏览器读到这样的字符串时，会试图进行解释。例如下面的这段文本 :
这是对 HTMLEncode 方法的测试。<br> 这里应该不会另起一行。
会被浏览器显示为 :
这是对 HTMLEncode 方法的测试。
这里应该不会另起一行。
为了避免此类问题，我们就需要使用 Server 对象的 HTMLEncode 方法，采用对应的不由浏览器解释的 HTML Character Code 替代 HTML 标记字符。所以，用下面的代码才能显示正确的 HTMLEncode 字符串，从而在浏览器中按你的需要输出文本。
<%
Response.write Server.HTMLEncode(" 这是对 HTMLEncode 方法的测试。<br> 这里应该不会另起一行。")%>
2、URLEncode 方法
就象 HTMLEncode 方法使客户可以将字符串翻译成可接受的 HTML 格式一样，Server 对象的 URLEncode 方法可以根据 URL 规则对字符串进行正确编码，当字符串数据以 URL 的形式传递到服务器时，在字符串中不允许出现空格，也不允许出现特殊字符。为此，如果你希望在发送字符串之前进行 URL 编码，可以使用 Server.URLEncode 方法。
3、MapPath 方法
MapPath 方法将指定的相对或虚拟路径映射到服务器上相应的物理目录上。
语法如下 :Server.MapPath(Path)
Path 指定要映射物理目录的相对或虚拟路径。若 Path 以一个正斜杠 (/) 或反斜杠 (\) 开始，则 MapPath 方法返回路径时将 Path 视为完整的虚拟路径。若 Path 不是以斜杠开始，则 MapPath 方法返回同 .asp 文件中已有的路径相对的路径。这里需要注意的是 MapPath 方法不检查返回的路径是否正确或在服务器上是否存在。
对于下列示例，文件 data.txt 和包含下列脚本的 test.asp 文件都位于目录 C:\Inetpub\Wwwroot\asp 下。C:\Inetpub\Wwwroot 目录被设置为服务器的宿主目录。下列示例使用服务器变量 PATH_INFO 映射当前文件的物理路径。以下脚本
<%= server.mappath(Request.ServerVariables("PATH_INFO"))%>
输出
c:\inetpub\wwwroot\asp\test.asp
由于下列示例中的路径参数不是以斜杠字符开始的，所以它们被相对映射到当前目录，此处是目录 C:\Inetpub\Wwwroot\asp。以下脚本
<%= server.mappath("data.txt")%>
<%= server.mappath("asp/data.txt")%>
输出
c:\inetpub\wwwroot\asp\data.txt
c:\inetpub\wwwroot\asp\asp\data.txt
4、CreateObject 方法
Server.CreateObject 恐怕是 ASP 中最为实用，也是最强劲的功能了。它用于创建已经注册到服务器上的 ActiveX 组件实例。这是一个非常重要的特性，因为通过使用 ActiveX 组件能够使你轻松地扩展 ActiveX 的能力，正是使用了 ActiveX 组件，你可以实现至关重要的功能，譬如数据库连接、文件访问、广告显示和其他 VBScript 不能提供或不能简单地依靠单独使用 ActiveX 所能完成的功能。正是因为这些组件才使得 ASP 具有了强大的生命力。
其语法如下：
Server.CreateObject("Component Name")
默认情况下，由 Server.CreateObject 方法创建的对象具有页作用域。这就是说，再当前 ASP 页处理完成之后，服务器将自动破坏这些对象。如果要创建有会话或应用程序作用域的对象，可以使用 <OBJECT> 标记并设置 SESSION 或 APPLICATION 的 SCOPE 属性，也可以在对话及应用程序变量中存储该对象。如下例程 :
<% Set Session("ad") = Server.CreateObject("MSWC.AdRotator")%>
这里需要注意的是，不能创建与内建对象同名的对象实例，否则，如下列脚本将返回错误。
<% Set Response = Server.CreateObject("Response") %>
至今为止，我们已经学习完了 ASP 所有的内建对象，从下一章起作者将开始介绍 ASP 内建 ActiveX 组件，这也是 ASP 运用中非常重要和实用的一部分。
……